PC World Interactive 7/PC World Interactive 7.iso/program/qbprog.EXE/HSCDINLE.BAS

BASIC Source File | 1980-01-10 | 17.5 KB | 513 lines

DECLARE SUB EkranYaz (Dosya$(), Diz$(), V1!)
DECLARE FUNCTION AdlibAra! ()
DECLARE SUB AnaMenu ()
DECLARE SUB Arkaplanciz ()
DECLARE SUB Bekle ()
DECLARE SUB Bekle1 ()
DECLARE SUB Bul (BulDosya$, Dosya$(), Diz$())
DECLARE SUB CerceveCiz (MenuYatay!, MenuDikey!, MenuYuksek!, MenuGenis!, MenuAd$)
DECLARE FUNCTION Dizin$ (Ara$)
DECLARE SUB Express (A$)
DECLARE SUB SecimDiz (Dosya$(), Diz$(), T$)
DECLARE SUB SecimDos (Dosya$(), Diz$())
DECLARE SUB Tarama ()
DECLARE SUB Yardim ()
DECLARE SUB Dinle (BYVAL Segm%, BYVAL Ofset%, BYVAL Bel%)
DECLARE SUB Kapa ()
DECLARE SUB YavasKapa ()
DECLARE SUB FontText ()
DECLARE SUB Ekransakla ()
DECLARE SUB EkranKoy ()
DECLARE SUB Bellek (A%)
TYPE Dosyalar
      Ax    AS INTEGER
      Bx    AS INTEGER
      Cx    AS INTEGER
      Dx    AS INTEGER
      bp    AS INTEGER
      si    AS INTEGER
      di    AS INTEGER
      Flags AS INTEGER
      Ds    AS INTEGER
      Es    AS INTEGER
      Dosya AS STRING * 64            'Dosya ismi bu deºiƒkende olacak
      HscDt AS STRING * 15000
END TYPE
DECLARE SUB Interruptx (Kesme AS INTEGER, Git AS Dosyalar, Gel AS Dosyalar)
DIM SHARED Yap AS Dosyalar
DIM SHARED Dosya$(301), Diz$(301), Mes$
DIM SHARED Sur$, Dz$, DosyaUzan$, EskiSur$, EskiDiz$, Adet1, Adet2
DIM SHARED BellekC%
ON ERROR GOTO Hatalar
A$ = COMMAND$: IF A$ <> "" THEN Express (A$)
DosyaUzan$ = ".HSC"
Arkaplanciz
EskiSur$ = LEFT$(CURDIR$, 2): EskiDiz$ = RIGHT$(CURDIR$, LEN(CURDIR$) - 2)
AnaMenu
Hatalar:
     CALL CerceveCiz(12, 9, 2, 40, "")
     LOCATE 13, 10
     IF ERR = 71 THEN
      PRINT "Disket yerleƒtir.<T-Tekrar>, <Esc-ÿptal>"
      DO
        DO: A$ = INKEY$: LOOP UNTIL A$ <> ""
        SELECT CASE A$
        CASE CHR$(27)
        CHDRIVE EskiSur$: CHDIR EskiDiz$: RESUME
        CASE "t", "T", CHR$(13)
        RESUME
        END SELECT
        BEEP
      LOOP
     END IF

FUNCTION AdlibAra
   OUT &H388, 4: Bekle1: OUT &H389, &H60: Bekle1
   OUT &H388, 4: Bekle1: OUT &H389, &H80: Bekle1
   A = INP(&H388)
   OUT &H388, 2: Bekle1: OUT &H389, &HFF: Bekle1
   OUT &H388, 4: Bekle1: OUT &H389, &H21: Bekle1
   Bekle
   B = INP(&H388)
   OUT &H388, 4: Bekle1: OUT &H389, &H60: Bekle1
   OUT &H388, 4: Bekle1: OUT &H389, &H80: Bekle1
   IF (A AND &HE0) = 0 AND (B AND &HE0) = &HC0 THEN AdlibAra = 1
END FUNCTION

SUB AnaMenu
     PCOPY 3, 0
     Ara = AdlibAra
     IF Ara <> 1 THEN
    CALL CerceveCiz(12, 9, 2, 40, "")
    LOCATE 13, 10: PRINT "Hata: Adlib uyumlu ses kartì bulunamadì!"
    DO: LOOP UNTIL INKEY$ <> ""
     ELSE
    Tarama
    CALL Bellek(11913): BellekC% = Yap.Ax
    CALL SecimDos(Dosya$(), Diz$())
     END IF
     CHDRIVE EskiSur$: CHDIR EskiDiz$
     SCREEN 2: SCREEN 0: COLOR 7, 1: CLS : END
END SUB

SUB Arkaplanciz
  SCREEN 2: SCREEN 0: FontText
  EkranAdresi = &HB800
  SCREEN , , 3, 0
  COLOR 9, 7: CLS
    A$ = "Bir Gürol DEMÿR & M.Doºan ÖZDEMÿR yapìmì, PS - (G&D), 1996..."
    A = LEN(A$)
    FOR I = 0 TO 1840 / A
       B = 80 - C
       IF B <= A THEN
      PRINT LEFT$(A$, B);
      PRINT RIGHT$(A$, A - B);
      C = A - B: D = C
       ELSE
      PRINT A$;
      C = C + A
       END IF
    NEXT
  DEF SEG = EkranAdresi + 256 * 3
    FOR I = 3680 + D * 2 TO 4000 STEP A * 2
       FOR Y = 1 TO A
    POKE I + (Y - 1) * 2, ASC(MID$(A$, Y, 1))
       NEXT
    NEXT
     CALL CerceveCiz(3, 4, 19, 70, " Dinlenecek müzik parçasì (.hsc) ")
     CALL CerceveCiz(4, 7, 2, 14, "")
     CALL CerceveCiz(4, 24, 2, 48, "")
     CALL CerceveCiz(7, 7, 14, 44, "Dosyalar")
     CALL CerceveCiz(7, 57, 14, 14, "Diz./Sürücü")
     LOCATE 13, 54: PRINT "Y"
     LOCATE 14, 54: PRINT "a"
     LOCATE 15, 54: PRINT "r"
     LOCATE 16, 54: PRINT "d"
     LOCATE 17, 54: PRINT "ì"
     LOCATE 18, 54: PRINT "m"
     LOCATE 12, 53: PRINT "■F1■"
     LOCATE 19, 53: PRINT "■F1■"
     COLOR 1, 3
      LOCATE 21, 8: PRINT CHR$(27); STRING$(42, "░"); CHR$(26);
      FOR I = 8 TO 19
    LOCATE I, 72: PRINT "░"
      NEXT
       LOCATE 8, 72: PRINT CHR$(24)
       LOCATE 20, 72: PRINT CHR$(25)
    SCREEN , , 0
       KEY 1, CHR$(254): KEY 2, CHR$(253): KEY 10, CHR$(255)
END SUB

SUB Bekle
     DEF SEG = 0
     FOR I = 1 TO 5
      A = PEEK(1132): DO
        IF PEEK(1052) <> PEEK(1050) THEN EXIT SUB
      LOOP UNTIL PEEK(1132) <> A
     NEXT
END SUB

SUB Bekle1
     DEF SEG = 0: A = PEEK(1132): DO: LOOP UNTIL PEEK(1132) <> A
END SUB

SUB Bellek (A%)
    Bos& = SETMEM(-1 * (A% + 17))
    Yap.Ax = &H4800: Yap.Bx = A% \ 16 + 1
    CALL Interruptx(&H21, Yap, Yap)
    IF (Yap.Flags AND 1) THEN PRINT "Hata": END
END SUB

SUB Bul (BulDosya$, Dosya$(), Diz$())
     Bulundu$ = Dizin$(BulDosya$)
     DO WHILE LEN(Bulundu$)
    DosyaAdsonu = INSTR(31, Bulundu$, CHR$(0))
    A$ = LEFT$(MID$(Bulundu$, 31, DosyaAdsonu - 31) + SPACE$(12), 12)
    IF (ASC(MID$(Bulundu$, 22, 4)) AND &H10) THEN
         IF LEFT$(A$, 2) <> ". " AND Diz < 300 THEN Diz$(Diz) = A$: Diz = Diz + 1
    ELSE
         IF CVL(MID$(Bulundu$, 27, 4)) > 0 AND Dos < 300 AND INSTR(A$, DosyaUzan$) > 0 THEN Dosya$(Dos) = A$: Dos = Dos + 1
    END IF
    Bulundu$ = Dizin$("")
     LOOP
    Adet1 = Dos: Adet2 = Diz
    FOR I = 1 TO Dos - 1: FOR Y = 0 TO Dos
       IF Dosya$(I) < Dosya$(Y) THEN SWAP Dosya$(I), Dosya$(Y)
    NEXT: NEXT
    FOR I = 1 TO Diz - 1: FOR Y = 0 TO Diz
       IF Diz$(I) < Diz$(Y) THEN SWAP Diz$(I), Diz$(Y)
    NEXT: NEXT
    Diz$(Diz) = "[-A-]": Diz = Diz + 1
    DEF SEG = 0: A = PEEK(&H475)
    IF A > 0 THEN Diz$(Diz) = "[-C-]": Diz = Diz + 1: Diz$(Diz) = "[-D-]": Diz = Diz + 1
END SUB

SUB CerceveCiz (MenuYatay, MenuDikey, MenuYuksek, MenuGenis, MenuAd$)
   COLOR 14, 1
   FOR I = 1 TO MenuYuksek - 1
     LOCATE MenuYatay + I, MenuDikey: PRINT "│"; STRING$(MenuGenis, " "); "│"
   NEXT
   LOCATE MenuYatay, MenuDikey
     PRINT "┌"; STRING$(MenuGenis, "─"); "┐"
   LOCATE MenuYatay + MenuYuksek, MenuDikey
     PRINT "└"; STRING$(MenuGenis, "─"); "┘";

   LOCATE MenuYatay, MenuDikey + (MenuGenis - LEN(MenuAd$)) \ 2 + 1: PRINT MenuAd$

IF MenuYatay <> 3 THEN EXIT SUB
   FOR I = 1 TO MenuGenis + 1
     POKE ((MenuYatay + MenuYuksek) * 160 + (MenuDikey + I) * 2 + 1), 9
   NEXT
   FOR I = 1 TO MenuYuksek + 1
     TR = ((MenuYatay + I - 1) * 160 + (MenuDikey + MenuGenis + 1) * 2 + 1)
     POKE TR, 9: POKE TR + 2, 9
   NEXT
END SUB

FUNCTION Dizin$ (Ara$) STATIC

      DIM DiskTransferYeri AS STRING * 44, Bak AS Dosyalar

      Bak.Ax = &H1A00
      Bak.Dx = VARPTR(DiskTransferYeri)
      Bak.Ds = VARSEG(DiskTransferYeri)
      Interruptx &H21, Bak, Bak

    IF LEN(Ara$) THEN
       Ara$ = Ara$ + CHR$(0)
       Bak.Dosya = Ara$

       Bak.Ax = &H4E00
       Bak.Cx = 1 + 2 + 4 + 16 + 32     'Bütün dosya ve dizinlere bak
                        '+1 =  Normal dosyalar dahil
                        '+2 =  Gizli dosyalar dahil
                        '+4 =  Sistem dosyalarì dahil
                        '+8 =  Disk labeli dahil
                        '+16 = Alt Dizinler dahil
                        '+32 = Arsiv dosyalarì dahil

       Bak.Dx = VARPTR(Bak.Dosya)
       Bak.Ds = VARSEG(Bak.Dosya)
    ELSE
       Bak.Ax = &H4F00
    END IF

    Interruptx &H21, Bak, Bak

    IF Bak.Flags AND 1 THEN            'Bulunamadì
       Dizin$ = ""
    ELSE
       Dizin$ = DiskTransferYeri       'Bulundu
    END IF
END FUNCTION

SUB EkranYaz (Dosya$(), Diz$(), V1)
    FOR I = 0 TO 12
     COLOR 15, 1
     LOCATE 8 + I, 9: PRINT SPACE$(42);
     LOCATE , 9: PRINT Dosya$(I + V1 * 13); : LOCATE , 24: PRINT Dosya$(I + 13 + V1 * 13); : LOCATE , 39: PRINT Dosya$(I + 26 + V1 * 13); : LOCATE , 59: PRINT Diz$(I);
     COLOR 30, 1
     IF Dosya$(I + V1 * 13) = Mes$ THEN LOCATE , 9: PRINT Mes$
     IF Dosya$(I + 13 + V1 * 13) = Mes$ THEN LOCATE , 24: PRINT Mes$
     IF Dosya$(I + 26 + V1 * 13) = Mes$ THEN LOCATE , 39: PRINT Mes$
    NEXT
END SUB

SUB Express (A$)
     ON LOCAL ERROR GOTO HataExpres
     IF INSTR(A$, "?") > 0 OR A$ = "H" OR A$ = "/H" OR A$ = "-H" THEN Yardim: END
     IF INSTR(A$, ".") = 0 THEN A$ = A$ + ".HSC"
     COLOR 7, 1: CLS : Ara = AdlibAra
     IF Ara <> 1 THEN
    PRINT "Hata: Adlib uyumlu ses kartì bulunamadì!"
     ELSE
    CLOSE #1: OPEN A$ FOR BINARY AS #1
    IF LOF(1) = 0 THEN CLOSE #1: KILL A$: END
    CALL Bellek(11913): BellekC% = Yap.Ax
    Yap.HscDt = SPACE$(LOF(1))
    GET #1, , Yap.HscDt
    Dinle VARSEG(Yap.HscDt), VARPTR(Yap.HscDt), BellekC%
    LOCATE , 1: PRINT "Geri dönüƒ için ≈EXIT≈ yazmanìz gerekir.": SHELL
    DO
       COLOR 7, 1: CLS
       LOCATE , 1: PRINT "Esc)Bitir   Enter)Dos'a geri dön"
       DO: A$ = INKEY$: LOOP UNTIL A$ <> ""
         IF A$ = CHR$(27) THEN YavasKapa: FOR I = 1 TO 5: Bekle: NEXT: Kapa: CLS : END
         IF A$ = CHR$(13) THEN CLS : LOCATE , 1: PRINT "Geri dönüƒ için ≈EXIT≈ yazmanìz gerekir.": SHELL
     LOOP
     END IF
HataExpres:
     Yardim
     END
END SUB

SUB SecimDiz (Dosya$(), Diz$(), T$)
     Ses = ASC(T$): COLOR 7, 1: LOCATE 5, 9: PRINT SPACE$(12)
     Yer1 = 8
  DO
     SELECT CASE Yer1
       CASE 21
      Yer1 = 20: R1 = R1 + 1
       CASE 7
      Yer1 = 8: R1 = R1 - 1
     END SELECT
     COLOR 15, 1
     FOR I = 0 TO 12
       LOCATE 8 + I, 58: PRINT LEFT$(" " + Diz$(I + R1) + SPACE$(12), 14)
     NEXT
     R = Yer1 - 8 + R1
     Sec1$ = Diz$(R)
     COLOR 1, 15: LOCATE Yer1, 58: PRINT LEFT$(" " + Sec1$ + "        ", 14)
     COLOR 14, 1: LOCATE 9 + R / 27, 72: PRINT "█"
     COLOR 15, 1: LOCATE 5, 26: PRINT RIGHT$(Sur$ + Dz$, 31);
     IF LEFT$(Sec1$, 1) <> "." AND LEFT$(Sec1$, 1) <> "[" THEN PRINT Sec1$
     DO: A$ = INKEY$: LOOP UNTIL A$ <> "": T$ = A$
     LOCATE Yer1, 58: PRINT LEFT$(" " + Sec1$ + "        ", 14)
     COLOR 1, 3: LOCATE 9 + R / 27, 72: PRINT "░"
     SELECT CASE ASC(A$)
        CASE 27
          EXIT SUB
        CASE 9
          EXIT SUB
        CASE 13
          IF LEFT$(Sec1$, 1) = "[" THEN CHDRIVE MID$(Sec1$, 3, 1) + ":" ELSE CHDIR RTRIM$(Sec1$)
          EXIT SUB
       CASE 255
         IF Ses = 1 THEN
         PCOPY 0, 2: Ekransakla
         EskiS$ = LEFT$(CURDIR$, 2): EskiD$ = RIGHT$(CURDIR$, LEN(CURDIR$) - 2)
         COLOR 7, 1: CLS : PRINT "Geri dönüƒ için ≈EXIT≈ yazmanìz gerekir."
         SHELL: CHDRIVE EskiS$: CHDIR EskiD$: EkranKoy: PCOPY 2, 0
         END IF
        CASE 254: Yardim
     END SELECT
     IF LEN(A$) = 2 THEN
    Z = ASC(RIGHT$(A$, 1))
    SELECT CASE Z
         CASE 79, 80, 81
           IF Diz$(R + 1) <> "" THEN Yer1 = Yer1 + 1
         CASE 71, 72, 73
           IF R > 0 THEN IF Diz$(R - 1) <> "" THEN Yer1 = Yer1 - 1
    END SELECT
     END IF
  LOOP
END SUB

SUB SecimDos (Dosya$(), Diz$())
     ON LOCAL ERROR GOTO SecimHata
     Yer = 8: Sat = 9
  DO
     SELECT CASE Sat
    CASE 9
      V = V1 * 13 + Yer - 8
    CASE 24, 39
      V = V1 * 13 + Yer - 8 + (Sat - 9) / 15 * 13
    CASE 54
      V1 = V1 + 1
    CASE -6
      IF V1 > 0 THEN V1 = V1 - 1
     END SELECT
     SELECT CASE Sat
       CASE 54, -6
    CALL EkranYaz(Dosya$(), Diz$(), V1)
    IF Sat = -6 THEN Sat = 9 ELSE Sat = 39
    V = V1 * 13 + Yer - 8 + ((Sat - 9) \ 15) * 13
     END SELECT
     Sec$ = Dosya$(V)
     COLOR 14, 1: LOCATE 21, 9 + V / 7: PRINT "█": LOCATE 9, 72: PRINT "█"
     COLOR 1, 15: LOCATE Yer, Sat - 1: PRINT " "; Sec$; " "
     COLOR 15, 1
     LOCATE 5, 9: PRINT SPACE$(12); : LOCATE , 26: PRINT SPACE$(46); : LOCATE , 9: PRINT Sec$; : LOCATE , 26: PRINT LEFT$(Sur$ + Dz$, 46)
     DO: A$ = INKEY$
       IF Sec$ = "" THEN A$ = CHR$(9): EXIT DO
     LOOP UNTIL A$ <> ""
     LOCATE Yer, Sat - 1: PRINT " "; Sec$; " ": IF Sec$ = Mes$ THEN COLOR 30, 1: LOCATE Yer, Sat: PRINT Mes$
     COLOR 1, 3: LOCATE 21, 9 + V / 7: PRINT "░"
     SELECT CASE ASC(A$)
      CASE 9
         T$ = CHR$(Ses)
         CALL SecimDiz(Dosya$(), Diz$(), T$)
         IF ASC(T$) = 13 THEN Tarama: Yer = 8: Sat = 9: V1 = 0
         IF ASC(T$) = 27 THEN IF Ses = 0 THEN EXIT SUB ELSE Ses = 0: LOCATE 5, 8: COLOR 15, 1: PRINT SPACE$(14); : LOCATE , 25: PRINT SPACE$(48): YavasKapa: FOR I = 1 TO 5: Bekle: NEXT: Kapa
      CASE 13
         IF Ses = 1 THEN Kapa ELSE Ses = 1
         Mes$ = Sec$
         CALL EkranYaz(Dosya$(), Diz$(), V1)
         CLOSE #1: OPEN Sur$ + Dz$ + Sec$ FOR BINARY AS #1
         Yap.HscDt = SPACE$(LOF(1))
         GET #1, , Yap.HscDt
         Dinle VARSEG(Yap.HscDt), VARPTR(Yap.HscDt), BellekC%
         S$ = RTRIM$(Sec$): MID$(Kayan$, 60, 15) = SPACE$(15): MID$(Kayan$, 76 - LEN(S$), LEN(S$)) = S$
       CASE 27: IF Ses = 0 THEN EXIT SUB ELSE Ses = 0: LOCATE 5, 8: COLOR 15, 1: PRINT SPACE$(14); : LOCATE , 25: PRINT SPACE$(48): YavasKapa: FOR I = 1 TO 5: Bekle: NEXT: Kapa: Mes$ = "": CALL EkranYaz(Dosya$(), Diz$(), V1)
       CASE 255
         IF Ses = 1 THEN
         PCOPY 0, 2: Ekransakla
         EskiS$ = LEFT$(CURDIR$, 2): EskiD$ = RIGHT$(CURDIR$, LEN(CURDIR$) - 2)
         COLOR 7, 1: CLS : PRINT "Geri dönüƒ için ≈EXIT≈ yazmanìz gerekir."
         SHELL: CHDRIVE EskiS$: CHDIR EskiD$: EkranKoy: PCOPY 2, 0
         END IF
       CASE 253: IF Ses = 1 THEN Ses = 0: LOCATE 5, 8: COLOR 15, 1: PRINT SPACE$(14); : LOCATE , 25: PRINT SPACE$(48): Kapa: Mes$ = "": CALL EkranYaz(Dosya$(), Diz$(), V1)
       CASE 254: Yardim
     END SELECT
     IF LEN(A$) = 2 THEN
    Z = ASC(RIGHT$(A$, 1))
    SELECT CASE Z
         CASE 80
           IF Dosya$(V + 1) <> "" AND Yer < 20 THEN Yer = Yer + 1 ELSE IF Dosya$(V + 1) <> "" THEN Yer = 8: Sat = Sat + 15
         CASE 79
        V = Adet1: V1 = (V \ 39) * 3: Sat = 9 + ((V - V1 * 13) \ 13) * 15: Yer = 7 + V - V1 * 13 - ((Sat - 9) \ 15) * 13
        CALL EkranYaz(Dosya$(), Diz$(), V1)
         CASE 81
        V = V + 39: Y = 8: IF V > Adet1 THEN V = Adet1: Y = 7
        V1 = (V \ 39) * 3: Sat = 9 + ((V - V1 * 13) \ 13) * 15: Yer = Y + V - V1 * 13 - ((Sat - 9) \ 15) * 13
        CALL EkranYaz(Dosya$(), Diz$(), V1)
         CASE 71
        Yer = 8: Sat = 9: V1 = 0: CALL EkranYaz(Dosya$(), Diz$(), V1)
         CASE 72
           IF Yer > 8 THEN Yer = Yer - 1 ELSE IF V <> 0 THEN IF Dosya$(V - 1) <> "" THEN Yer = 20: Sat = Sat - 15
         CASE 73
        V = V - 39: Y = 8: IF V < 0 THEN V = 1: Y = 7
        V1 = (V \ 39) * 3: Sat = 9 + ((V - V1 * 13) \ 13) * 15
        Yer = Y + V - V1 * 13 - ((Sat - 9) \ 15) * 13
        CALL EkranYaz(Dosya$(), Diz$(), V1)
         CASE 77
           IF Dosya$((V \ 13) * 13 + 13) <> "" THEN
               Sat = Sat + 15
               DO
            IF Dosya$(V + 13) <> "" THEN EXIT DO ELSE Yer = Yer - 1: V = V - 1
               LOOP
           END IF
         CASE 75
           IF V > 0 THEN Sat = Sat - 15
         CASE 32
        PCOPY 0, 2
        CALL CerceveCiz(12, 9, 2, 40, "")
        LOCATE 13, 11: PRINT RTRIM$(Sec$); " silinsin mi? E)vet H)ayìr"
        DO: A$ = INKEY$: LOOP UNTIL A$ <> ""
            IF A$ = "E" OR A$ = "e" THEN
               CLOSE : KILL Sec$: Tarama: Yer = 8: Sat = 9: V1 = 0
            ELSE
               PCOPY 2, 0
            END IF
         CASE 19
        PCOPY 0, 2
        CALL CerceveCiz(12, 9, 2, 40, ""): LOCATE 13, 10: PRINT "Yeni dosya ismini giriniz:"
        S$ = LEFT$(Sec$ + SPACE$(12), 12): F = LEN(RTRIM$(Sec$)) + 1: IF F > 12 THEN F = 12
              DO
             COLOR 1, 7: LOCATE 13, 37: PRINT S$: LOCATE 13, 36 + F, 1
             IF ins = 0 THEN LOCATE , , , 7, 8 ELSE LOCATE , , , 7, 13
             DO: A$ = INKEY$: LOOP UNTIL A$ <> ""
             LOCATE , , 0
             IF LEN(A$) = 2 THEN Z = ASC(RIGHT$(A$, 1)) ELSE Z = ASC(A$)
             SELECT CASE Z
                   CASE 27: PCOPY 2, 0: EXIT DO
                   CASE 13: CLOSE : Hata = 0: NAME Sur$ + Dz$ + Sec$ AS Sur$ + Dz$ + RTRIM$(S$)
                   IF Hata = 0 THEN Dosya$(V) = S$
                   PCOPY 2, 0: EXIT DO
                   CASE 75: IF F > 1 THEN F = F - 1
                   CASE 77: IF F < 12 THEN F = F + 1
                   CASE 82: IF ins = 0 THEN ins = 1 ELSE ins = 0
                   CASE 83: S$ = LEFT$(S$, F - 1) + RIGHT$(S$, 12 - F) + " "
                   CASE 8: S$ = LEFT$(S$, F - 1) + RIGHT$(S$, 12 - F) + " ": IF F > 1 THEN F = F - 1
                   CASE ELSE
                  IF LEN(A$) = 1 THEN
                    IF ins = 1 THEN MID$(S$, F) = A$ ELSE S$ = LEFT$(LEFT$(S$, F - 1) + A$ + RIGHT$(S$, 12 - F + 1), 12)
                    IF F < 12 THEN F = F + 1
                  END IF
             END SELECT
               LOOP
    END SELECT
     END IF
  LOOP
EXIT SUB
SecimHata:
  Hata = 1: RESUME NEXT
END SUB

SUB Tarama
     PCOPY 3, 0
     CALL CerceveCiz(12, 9, 2, 40, "")
     LOCATE 13, 10: PRINT "Dosyalarì tarìyorum, lütfen bekleyiniz.."
     FOR I = 0 TO 301: Dosya$(I) = "": Diz$(I) = "": NEXT
     D$ = CURDIR$: IF LEN(D$) = 3 THEN D$ = LEFT$(D$, 2)
     Ara$ = D$ + "\*.*"
     CALL Bul(Ara$, Dosya$(), Diz$())
     FOR I = 0 TO 12
       COLOR 15, 1
       LOCATE 8 + I, 9: PRINT SPACE$(42);
       LOCATE , 9: PRINT Dosya$(I); : LOCATE , 24: PRINT Dosya$(I + 13); : LOCATE , 39: PRINT Dosya$(I + 26); : LOCATE , 59: PRINT Diz$(I);
       COLOR 30, 1
     IF Dosya$(I) = Mes$ THEN LOCATE , 9: PRINT Mes$
     IF Dosya$(I + 13) = Mes$ THEN LOCATE , 24: PRINT Mes$
     IF Dosya$(I + 26) = Mes$ THEN LOCATE , 39: PRINT Mes$
     NEXT
     Sur$ = LEFT$(CURDIR$, 3): Dz$ = ""
     IF LEN(CURDIR$) > 3 THEN Dz$ = RIGHT$(CURDIR$, LEN(CURDIR$) - 3) + "\"
END SUB

SUB Yardim
    PCOPY 0, 2
    Sa = CSRLIN: Su = POS(0)
    COLOR 15, 1: CLS
    CALL CerceveCiz(1, 2, 2, 76, "")
    COLOR 15, 1: LOCATE 2, 4: PRINT "HSCDINLE, Gürol DEMÿR & M.Doºan ÖZDEMÿR - (c) 1996 Shareware versiyon 1.01"
    CALL CerceveCiz(5, 2, 17, 76, "Yardìm")
    CALL CerceveCiz(6, 7, 2, 67, ""): LOCATE 6, 10: PRINT "Gereksinim": COLOR 15, 1:
    LOCATE 7, 9: PRINT "Bu ≈Hsc≈ dinletici program, adlib uyumlu ses kartlarìnda çalìƒìr."
    CALL CerceveCiz(10, 13, 6, 52, "Tuƒlarìn iƒlevleri (Melodi)"): COLOR 15, 1
    LOCATE 11, 15: PRINT "Dinleme                   : Enter"
    LOCATE 12, 15: PRINT "Yavas kapatma             : Esc"
    LOCATE 13, 15: PRINT "Hìzlì Kapatma             : F2"
    LOCATE 14, 15: PRINT "Müzik ile Dos'da gezinti  : F10"
    LOCATE 15, 15: PRINT "Dinlenecek parçanìn seçimi: Cursor hareket Tuƒlarì"
    CALL CerceveCiz(18, 5, 3, 31, "Tuƒlarìn iƒlevleri (Dosya)"): COLOR 15, 1
    LOCATE 19, 7: PRINT "Alt+R  : Yeniden isimlendirme"
    LOCATE 20, 7: PRINT "Alt+D  : Müzik dosyasìnì sil"
    CALL CerceveCiz(19, 49, 2, 27, "Express Tsr"): COLOR 15, 1
    LOCATE 20, 51: PRINT "HSCDINLE müzikdosyasì.adì"
    DO: LOOP UNTIL INKEY$ <> ""
    LOCATE Sa, Su
    PCOPY 2, 0
END SUB